/**
 * Esfera. 
 * David Pena.  
 * 
 * Distribucion aleatoria uniforme sobre la superficie de una esfera.
 *
 * Modifications by subpixel:
 *  removal of unused global arrays;
 *  calculate end point of a hair as the hairlength distance from the hair base, not as a point at a fixed distance from the centre of the sphere (which causes hairs to stretch);
 *  reverse Ymouse reactivity so ball spins in the direction of mouse movement instead of against it;
 *  added start/pause functionality on mouse click event
 */


import processing.opengl.*;

// ------------------------------------------------------------
// Global variables
// ------------------------------------------------------------

boolean looping = false; // Opening state of the sketch. Set true to open un-paused.

int cuantos = 1200;  // Number of hairs
pelo[] lista ;  // Array/list of hairs
float radio;    // Radius of the sphere
float hairmin;  // Minimum hair length
float hairmax;  // Maximum hair length
float rx = 0;
float ry = 0;

// ------------------------------------------------------------
// Main setup method.
// ------------------------------------------------------------
void setup()
{
  size(640, 480, OPENGL);  // Set the canvas size, and use OpenGL rendering
  
  if (!looping) noLoop();  // Opportunity to open the sketch in a paused state

  radio = height/4;  // The central sphere is half the window height (radius therefore 1/4 window height)
  hairmin = radio * 0.1;  // Minimum hair length set proportionally to the sphere radius
  hairmax = radio * 0.4;  // Maximum hair length ser proportionally to the sphere radius
  
  lista = new pelo[cuantos];  // Initialise the array for the number of hairs

  for (int i=0; i<cuantos; i++)  // For each hair...
  {
    lista[i] = new pelo();  // Create a new hair object and save it in the array
  }

  noiseDetail(3);
}

// ------------------------------------------------------------
// Main draw method.
// ------------------------------------------------------------
void draw()
{
  background(0);
  translate(width/2,height/2);  // Position the coordinate origin at the centre of the window

  // Ease towards current mouse "position" (orientation determined by mouse position)... "step 10% of the current difference each frame"
  float rxp = ((mouseX-(width/2))*0.005);
  float ryp = (((height/2)-mouseY)*0.005);
  rx = (rx*0.9)+(rxp*0.1);
  ry = (ry*0.9)+(ryp*0.1);
  rotateY(rx);
  rotateX(ry);

  fill(0); // Black...
  noStroke(); // No outline...
  sphere(radio);  // Draw the sphere (to occlude hairs on the side away from the viewpoint)

  for (int i=0;i<cuantos;i++){  // For each hair...
    lista[i].dibujar();  // Calculate and draw the hair
  }
}

// ------------------------------------------------------------
// Class for an individual hair.
// ------------------------------------------------------------
class pelo
{
  // MEMBER VARIABLES

  // The location of the base of the hair (or at least the angles from the centre of the sphere)
  // is fixed at the creation of the hair object instance.
  // Use different methods to choose angles phi and theta, since using
  // random(TWO_PI) for both tends to make the distribution of hairs clumpy.
  float phi = random(TWO_PI);  // Any angle in 360 degrees
  float theta = asin( random(-radio,radio) / radio );

  // The length of the hair is fixed at the creation of the hair object instance.
  float hairlength = random(hairmin, hairmax);

  // METHODS
  
  // The draw method for the hair.
  void dibujar(){
    // Calculate the position of the base of the hair on the sphere
    float x = radio * cos(theta) * cos(phi);
    float y = radio * cos(theta) * sin(phi);
    float z = radio * sin(theta);
    
    // Determine some offset angle(s) for the end of the hair
    float off  = ( noise( millis() * 0.0005, sin(phi)     ) - 0.5 ) * PI;
    float offb = ( noise( millis() * 0.0007, sin(z) * 0.01) - 0.5 ) * PI;
    
    float thetaff = theta + off;
    float phff = phi + offb;
    
    // Calculate the position of the end of the hair (which will be the hairlength from the base of the hair)
    float x1 = x + hairlength * cos(thetaff) * cos(phff);
    float y1 = y + hairlength * cos(thetaff) * sin(phff);
    float z1 = z + hairlength * sin(thetaff);
    
    beginShape(LINES);
    stroke(0);  // No stroke when locating to the base of the hair
    vertex(x, y, z);  // The base of the hair
    stroke(200, 150);
    vertex(x1, y1, z1);  // The tip of the hair
    endShape();
  }
}

// ------------------------------------------------------------
// Start / stop (pause) the main loop each time a mouse
// button is pressed.
// Added by subpixel to get a closer look at the details
// without having to take a screenshot, and also to
// give the user a chance to kill the CPU / GPU load on
// their machine if/when the applet is embedded on a page
// and the user no longer cares for the animation.
// ------------------------------------------------------------
void mousePressed()
{
  if (looping)
  {
    // Pause the main loop
    noLoop();
    looping = false;
  }
  else
  {
    // (Re-)start the main loop
    loop();
    looping = true;
  }
}